Action 1 (default)

action log all

//* ====================================================================================================>
//*     
//*     DESCRIPTION AND NOTES
//*
//*     - This task will upload speciifed files or folders to the root server.
//*
//* ====================================================================================================>


//* ====================================================================================================>
//*
//*     SET SOME PARAMETERS
//*
//*     - These parameters can be used to control the behavior of the action
//*
//* ====================================================================================================>

action parameter query "FilePath" with description "Please enter full path to file or folder.  Leave a trailing trailing / for Mac/Linux to indicate folder upload mode."
parameter "Exportfolder" = "{data folder of client as string & ("/FileUploader/")}"
parameter "maximumfilesizeMB" = "100"

//action uses wow64 redirection false

//create working directory
folder create "{parameter "Exportfolder"}"

//enter single or multiple file copy - we don't need different logic for those on mac/linux
//check sizing
if {sum of sizes of files of folder (parameter "FilePath")|0/1024/1024 > parameter "maximumfilesizeMB" as integer}
        exit 413
	//check existance
    elseif {if ((character (length of it - 1) of it) of parameter "FilePath" = "/") then (not exists folder (parameter "FilePath")) else (not exists file (parameter "FilePath"))}
        exit 404
endif
	//remove old stuff 
     folder delete "{parameter "Exportfolder" & "temp"}"
	//fresh working folder
    folder create "{parameter "Exportfolder" & "temp"}" 
	//copy file or folder to BigFix temp folder
    wait cp -R "{parameter "FilePath"}" "{parameter "Exportfolder" & "temp"}"  

    parameter "timestamp" = "{(((month of it as two digits & "-" & day_of_month of it as two digits & "-" & year of it as string) of date(local time zone) of it & "_" & (two digit hour of it as string & two digit minute of it as string) of time (local time zone) of it) of now)}"

	//compress and remove directory structure - this is just the option I chose since I think it extracts cleaner  
    wait tar -zcvf "{parameter "Exportfolder"}{(computer name as lowercase & "_" & parameter "timestamp" & "_fileupload.tar.gz")}" -C "{parameter "Exportfolder" & "temp"}" .
 
//save existing ArchiveManager settings
parameter "prevOperatingMode" = "{if (exists setting whose (name of it = "_BESClient_ArchiveManager_OperatingMode" and exists value of it) of client) then value of setting "_BESClient_ArchiveManager_OperatingMode" of client else "0"}"
parameter "prevMaxArchiveSize" = "{if (exists setting whose (name of it = "_BESClient_ArchiveManager_MaxArchiveSize" and exists value of it) of client) then value of setting "_BESClient_ArchiveManager_MaxArchiveSize" of client else "52428800"}"

//limit upload results to 100MB and start the upload asap.
setting "_BESClient_ArchiveManager_MaxArchiveSize"="109715200" on "{parameter "action issue date" of action}" for client
setting "_BESClient_ArchiveManager_OperatingMode"="2" on "{parameter "action issue date" of action}" for client
setting "_BESClient_ArchiveManager_FileSet-AVPFileUpload"="{parameter "Exportfolder"}{(computer name as lowercase & "_" & parameter "timestamp" & "_fileupload.tar.gz")}" on "{parameter "action issue date" of action}" for client
archive now

//restore previous ArchiveManager settings 
setting "_BESClient_ArchiveManager_OperatingMode"="{parameter "prevOperatingMode"}" on "{parameter "action issue date" of action}" for client
setting "_BESClient_ArchiveManager_MaxArchiveSize"="{parameter "prevMaxArchiveSize"}" on "{parameter "action issue date" of action}" for client

//cleanup after ourselves												
folder delete "{parameter "Exportfolder" & "temp"}"
delete "{parameter "Exportfolder"}{(computer name as lowercase & "_" & parameter "timestamp" & "_fileupload.tar.gz")}"