Action 1 (default)

// Downloads

//  - This is the commandline 7zip console which is use to unpack installers
//  - https://www.virustotal.com/en/file/2a3afe19c180f8373fa02ff00254d5394fec0349f5804e0ad2f6067854ff28ac/analysis
prefetch 7za920.zip sha1:9ce9ce89ebc070fea5d679936f21f9dde25faae0 size:384846 http://softlayer-dal.dl.sourceforge.net/project/sevenzip/7-Zip/9.20/7za920.zip

//  - This unzip is a compiled verion of unzip v5.52 fom http://info-zip.org/
//  - https://www.virustotal.com/en/file/8d9b5190aace52a1db1ac73a65ee9999c329157c8e88f61a772433323d6b7a4a/analysis
prefetch unzip.exe sha1:e1652b058195db3f5f754b7ab430652ae04a50b8 size:167936 http://software.bigfix.com/download/redist/unzip-5.52.exe

//  This is the driver from Epson
prefetch epson_driver_installer.exe sha1:0b7e771f90ba605898048f3ffb2283cfaf4bbf32 size:11385120 https://ftp.epson.com/drivers/epson13936.exe

// END of Downloads


// Add unzip.exe & 7za920.zip to the client utility cache since they are used in many tasks
//  - This will prevent these from from being redownloaded multiple times to the client ( as long as they are in either the download or utility cache )
utility __Download\unzip.exe
utility __Download\7za920.zip

// use the unzip redistributable to unzip the 7zip command line utility
waithidden __Download\unzip.exe -o "{pathname of file "7za920.zip" of folder "__Download" of client folder of current site}" -d "{pathname of folder "__Download" of client folder of current site}"

// use 7zip to extract the installers from the Epson download
waithidden "{(pathname of file "7za.exe" of folder "__Download" of client folder of current site)}" x -y -o"{pathname of folder "__Download" of client folder of current site}\Epson_Driver" "{pathname of file "epson_driver_installer.exe" of folder "__Download" of client folder of current site}"

// the security catalog for some Epson scanners need added to the certificate store first (might be able to verify this is needed first using certutil)
waithidden cmd.exe /C { if (x64 of operating system) then (pathname of windows folder & "\sysnative") else (pathname of system folder) }\certutil -f -addstore trustedpublisher "{(pathname of file whose(name of it as lowercase ends with ".cat") of folder "Epson_Driver" of folder "__Download" of client folder of current site)}"

// Install
waithidden "{pathname of file "Setup.exe" of folder "Epson_Driver" of folder "__Download" of client folder of current site}" /SI -sms /Nodisp

// Delete Desktop Icon
delete "{pathnames of folders (value of variable "PUBLIC" of environment)}\Desktop\EPSON Scan.lnk"

// Move start menu folder (only if the 'Digital Imaging' folder exists - for Lab Computers)
if{exists folders "Digital Imaging" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}
	// Delete destination folder (in case it already exists)
    folder delete "{pathname of folders "Digital Imaging" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}\EPSON Scan"
	// Move the 'EPSON Scan' folder into the 'Digital Imaging' folder in the start menu
    dos move /Y "{pathname of (folders "EPSON\EPSON Scan" of it;folders "EPSON Scan" of it) of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}" "{pathname of folders "Digital Imaging" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}"
    
else
// This will move the 'EPSON Scan' folder out of the 'EPSON' folder if created there. Older drives do this, newer ones do not, so this unifies them.
    if{exists folders "EPSON\EPSON Scan" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}
		// Delete destination folder (in case it already exists)
        folder delete "{pathname of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}\EPSON Scan"
        dos move /Y "{pathname of folders "EPSON\EPSON Scan" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}" "{pathname of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}"
    endif
endif

// Delete the 'EPSON' folder that remains, only if it exists and is empty ( in case other items remain in this folder that existed before this action was run, the folder will not be deleted )
if{exists folders "EPSON" whose(0 = number of descendants of it) of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}
    folder delete "{pathname of folders "EPSON" of folders "Microsoft\Windows\Start Menu\Programs" of folders (value of variable "ALLUSERSPROFILE" of environment)}"
endif

    

This action will be considered successful when the applicability relevance evaluates to false.