Action 1 (default)

action parameter query "BIOS_Password" with description "Enter BIOS Password, or leave blank if none." and with default value " "

// -- START:DOWNLOADS -------------------------

prefetch BIOS_Update.exe sha1:505ef5a4b06706b0ed7aa228f3c020af2273a284 size:8532512 https://downloads.dell.com/FOLDER02375461M/1/O9010A19.exe

// -- END:DOWNLOADS ---------------------------


// DELETE: current log file if it exists
delete "{ pathname of folder "__BESData\__Global\Logs" of parent folder of client }\install_Dell_BIOS_Update.log"

// INSTALL: BIOS Update
if{ ( 4 <= length of (it as trimmed string) of (parameter "BIOS_Password") ) }
    waithidden __Download\BIOS_Update.exe /s /p={ (parameter "BIOS_Password") as trimmed string } /l="{ pathname of folder "__BESData\__Global\Logs" of parent folder of client }\install_Dell_BIOS_Update.log"
else
    waithidden __Download\BIOS_Update.exe /s /l="{ pathname of folder "__BESData\__Global\Logs" of parent folder of client }\install_Dell_BIOS_Update.log"
endif

// Exit Codes:
//		0 = SUCCESSFUL
//		1 = UNSUCCESSFUL  (FAILURE)
//		2 = REBOOT_REQUIRED  (SUCCESSFUL)
//		3 = DEP_SOFT_ERROR
//		4 = DEP_HARD_ERROR
//		5 = QUAL_HARD_ERROR
//		6 = REBOOTING_SYSTEM  (SUCCESSFUL)
//		7 = ? (wrong password)
//		8 = ?
//		9 = RPM_VERIFY_FAILED

// http://en.community.dell.com/techcenter/enterprise-client/w/wiki/3462.dup-bios-updates
// Report failure if bad return code, continue if good return code
continue if{ exists (exit codes of action) whose(it = 2 OR it = 0 OR it = 6) }

notify client ForceRefresh

action requires restart "DellUpdatesInstalled"

    

This action will be considered successful when the applicability relevance evaluates to false.