Fixlet | Configuration: BES Client - Recommended Client Settings - Universal

Configuration: BES Client - Recommended Client Settings - Universal
Log In or Register to download the BES file, and more.

1 Votes

Versioning - This is the latest version.

1	Configuration: Recommended Client Settings	12/6/2013 3:48:01 PM
2	Configuration: BES Client - Recommended Client Settings - Universal	1/12/2015 9:59:25 AM
3	Configuration: BES Client - Recommended Client Settings - Universal	7/2/2015 8:15:30 AM

Description

This fixlet will change the default BigFix Client setttings.

Property Details

ID	6117
Status	Alpha - Code that was just developed
Title	Configuration: BES Client - Recommended Client Settings - Universal
Domain	BESC
Category	Configuration
Download Size	0
Source	Internal
Source ID	jgs194
Source Release Date	1/12/2015 12:00:00 AM
Added by	jgstew on 7/2/2015 8:15:30 AM
Last Modified by	jgstew on 7/2/2015 8:15:30 AM
Counters	18736 Views / 171 Downloads
User Rating	* Average over 2 ratings. ** Log In or Register to add your rating.

Relevance

Relevance 2999697

Used in 2 fixlets

* Results in a true/false

(
    not exists settings "_BESClient_Download_PreCacheStageDiskLimitMB" whose
    (
        (
            it >= 5000
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Download_NormalStageDiskLimitMB" whose
    (
        (
            it >= 20000
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Download_DownloadsCacheLimitMB" whose
    (
        (
            it >= 10000
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Download_UtilitiesCacheLimitMB" whose
    (
        (
            it >= 200
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Download_MinimumDiskFreeMB" whose
    (
        (
            it >= 2000
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Download_RetryMinutes" whose
    (
        (
            it <= 5
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Report_MinimumInterval" whose
    (
        (
            it >= 30
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Log_Days" whose
    (
        (
            it >= 30
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Comm_CommandPollIntervalSeconds" whose
    (
        (
            it <= 43200
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)
OR
(
    not exists settings "_BESClient_Comm_CommandPollEnable" whose
    (
        (
            it = 1
        )
        of
        (
            it as string as integer
        )
        of values of it
    )
    of client
)

Actions

Action 1 (default)

Action Link Click here to deploy this action.

Script Type BigFix Action Script

//BEGIN: Set recommended client settings
//    See info about these settings here:  https://www.ibm.com/developerworks/community/wikis/home?lang=en#/wiki/Tivoli%20Endpoint%20Manager/page/Configuration%20Settings

// This is better set through the clientsettings.cfg file.
if {not exists setting "_BESClient_Resource_StartupNormalSpeed" of client}
    setting "_BESClient_Resource_StartupNormalSpeed"="1" on "{now as string}" for client
endif

// Enable Command Polling if not enabled
if { not exists settings "_BESClient_Comm_CommandPollEnable" whose( (it = 1) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Comm_CommandPollEnable"="1" on "{parameter "action issue date" of action}" for client
endif

// This will set command polling to once every 12 hours, if not already enabled more aggressively
if { not exists settings "_BESClient_Comm_CommandPollIntervalSeconds" whose( (it <= 43200) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Comm_CommandPollIntervalSeconds"="43200" on "{parameter "action issue date" of action}" for client
endif

// It is helpful for the client to store at least 30 days of logs for troubleshooting & reporting
if { not exists settings "_BESClient_Log_Days" whose( (it >= 30) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Log_Days"="30" on "{parameter "action issue date" of action}" for client
endif

// By default, the client will send reports no more often than once every 15 seconds, but this is more often than needed. 
//    This should be increased to at least 30 seconds, but 30-90 seconds is reasonable.
//    This will reduce the load on the Relays and Root Server. This could slow reporting in the console somewhat.
if { not exists settings "_BESClient_Report_MinimumInterval" whose( (it >= 30) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Report_MinimumInterval"="30" on "{parameter "action issue date" of action}" for client
endif

// Download_RetryMinutes should be lower than 5 min, otherwise baselines could be held up.
if { not exists settings "_BESClient_Download_RetryMinutes" whose( (it <= 5) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Download_RetryMinutes"="1" on "{parameter "action issue date" of action}" for client
endif


if{ not exists settings "_BESClient_Download_MinimumDiskFreeMB" whose( (it >= 2000) of (it as string as integer) of values of it ) of client }
    setting "_BESClient_Download_MinimumDiskFreeMB"="2000" on "{parameter "action issue date" of action}" for client
endif

if {not exists settings "_BESClient_Download_UtilitiesCacheLimitMB" whose( (it >= 200) of (it as string as integer) of values of it ) of client}
    setting "_BESClient_Download_UtilitiesCacheLimitMB"="200" on "{parameter "action issue date" of action}" for client
endif


if {not exists settings "_BESClient_Download_DownloadsCacheLimitMB" whose( (it >= 10000) of (it as string as integer) of values of it ) of client}
    setting "_BESClient_Download_DownloadsCacheLimitMB"="10000" on "{parameter "action issue date" of action}" for client
endif

if {not exists settings "_BESClient_Download_NormalStageDiskLimitMB" whose( (it >= 20000) of (it as string as integer) of values of it ) of client}
    setting "_BESClient_Download_NormalStageDiskLimitMB"="20000" on "{parameter "action issue date" of action}" for client
endif

if {not exists settings "_BESClient_Download_PreCacheStageDiskLimitMB" whose( (it >= 5000) of (it as string as integer) of values of it ) of client}
    setting "_BESClient_Download_PreCacheStageDiskLimitMB"="5000" on "{parameter "action issue date" of action}" for client
endif

//END: Set recommended client settings

notify client ForceRefresh

Success Criteria

This action will be considered successful when the applicability relevance evaluates to false.

Action 2

Action Link Click here to review this task in the bigfix.me Content Database.

Script Type URL

http://bigfix.me/cdb/fixlet/3942

Sharing

Social Media:

Comments

	jgstew - 7/1/2015 5:20:46 PM (from another version)
	Oh, interesting. Just after _BESClient_Download_DownloadsCacheLimitMB ... I'll have to fix that. I bet I missed that in my testing because that specific statement wasn't run due to the IF statement before it on my systems.

	strawgate - 7/1/2015 3:11:21 PM (from another version)
	Didn't realize it got rid of carriage returns... The error is on line 49 to 51 and it is an extra space before the equals sign.

	strawgate - 7/1/2015 3:10:26 PM (from another version)
	There is an error on this line: if {not exists settings "_BESClient_Download_DownloadsCacheLimitMB" whose( (it >= 10000) of (it as string as integer) of values of it ) of client} setting "_BESClient_Download_DownloadsCacheLimitMB" ="10000" on "{parameter "action issue date" of action}" for client endif The space before the equals sign causes the client to error out with: Command succeeded setting "_BESClient_Comm_CommandPollEnable"="1" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Comm_CommandPollIntervalSeconds"="43200" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Log_Days"="30" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Report_MinimumInterval"="30" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Download_RetryMinutes"="1" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Download_MinimumDiskFreeMB"="2000" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command succeeded setting "_BESClient_Download_UtilitiesCacheLimitMB"="200" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244) Command failed (Missing setting value) setting "_BESClient_Download_DownloadsCacheLimitMB" ="10000" on "Wed, 01 Jul 2015 21:53:17 +0000" for client (group:243,action:244)

Search for:	Relevance	Fixlets/Tasks
	Analyses	BFI Signatures
	Dashboard/Wizard

Title	Keywords	Description
Relevance	Domain	ActionScript
Mime	Signature Content	(clear all)


Content Search Share Learn Projects	Utilities View SCM Scripts Base64 Converter Shell to Action Script	About About Us Tour FAQ Terms Contact Us	BigFix Resources Download BigFix Support Forum Github/Bigfix

Configuration: BES Client - Recommended Client Settings - Universal Log In or Register to download the BES file, and more.