Run: Driver Restore - Dell Command Update - Windows
| 0 Votes |
Description
This task will install Dell Updates using Dell Command Update.
See Installer Task: Install/Update: Dell Command Update - Windows (Only once for each client)
Property Details
| 6216 | |
| Alpha - Code that was just developed | |
| Run: Driver Restore - Dell Command Update - Windows | |
| BESC | |
| Software Sharing | |
| 0 | |
| Internal | |
| jgstew | |
| 10/25/2014 12:00:00 AM | |
| jgstew on 9/28/2015 4:53:23 PM | |
| jgstew on 9/28/2015 4:53:23 PM | |
| 5241 Views / 35 Downloads | |
* Average over 0 ratings.
** Log In or Register to add your rating.
|
Relevance
Windows Only (Relevance 2997197)
/* Windows Only */ windows of operating system
/* Windows Vista or Higher */ version of operating system >= "6.0"
/* DELL Only */ exists values "vendor" whose(it as string as uppercase contains "DELL") of structures "bios_information" of smbios
/* check for supported model: OptiPlex, Latitude, Precision, Venue Tablets, XPS */ exists ((value "product_name" of structures "system_information" of smbios) as string as uppercase) whose(it starts with "OPTIPLEX" OR it starts with "LATITUDE" OR it starts with "PRECISION" OR it starts with "XPS" OR it starts with "VENUE")
| Used in 1 fixlet | * Results in a true/false |
/* the CLI is available */ exists files "dcu-cli.exe" whose(version of it >= "2.1.0.218") of folders ( unique value of pathnames of folders ( unique values of (it as string) of ( ( values "InstallLocation" of keys whose(value "DisplayName" of it as string as trimmed string starts with "Dell Command | Update" AND value "DisplayVersion" of it as string as version >= "2.0.0") of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of (registry;native registry) ) ; ( values "InstallPath" of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Dell\CommandUpdate" of (registry;native registry) ) ) ) )
| Used in 1 fixlet | * Results in a true/false |
not exists node values whose(it contains "CLI: Installation Complete") of xpaths "/LogEntries/LogEntry/message/text()[contains(.,'CLI: Installation Complete')]" of xml documents of files "ActivityLog.xml" of folders "Logs_DellDriverRestore" of folders "__BESData\__Global\Logs" of parent folder of client
Actions
Action 1 (default)
Action Link Click
here to deploy this action.
Script Type
BigFix Action Script
parameter "BEFORE_NumDevMissingDrivers" = "{number of select objects "* FROM Win32_PnPEntity WHERE Status <> 'OK' OR ConfigManagerErrorCode != 0" of wmis}"Success Criteria
// http://support.bigfix.com/fixlet/documents/WinActions_20081110.pdf
action launch preference low-priority
// INSTALL: Drivers
waithidden "{ pathname of file "dcu-cli.exe" whose(version of it >= "2.0.0.565") of folder ( unique value of pathnames of folders ( unique values of (it as string) of ( ( values "InstallLocation" of keys whose(value "DisplayName" of it as string as trimmed string starts with "Dell Command | Update" AND value "DisplayVersion" of it as string as version >= "2.0.0") of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of (registry;native registry) ) ; ( values "InstallPath" of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Dell\CommandUpdate" of (registry;native registry) ) ) ) ) }" /silent /log "{ (pathname of folder "__BESData\__Global\Logs" of parent folder of client) }\Logs_DellDriverRestore" /driverRestore
// Return Codes:
// 0 = OK/Success
// 1 = Reboot Required
// 2 = Fatal Error
// 3 = Error
// 4 = Invalid System
parameter "AFTER_NumDevMissingDrivers" = "{number of select objects "* FROM Win32_PnPEntity WHERE Status <> 'OK' OR ConfigManagerErrorCode != 0" of wmis}"
parameter "AFTER_RunTime" = "{ (active start time of active action) - now }"
// http://www.dell.com/support/Manuals/us/en/19/Topic/dell-comnd-update-v2.0/DCU_formerly_DCSU_UG-v2/en-us/GUID-E3858402-1574-40EB-9ADB-3E9C4C9DB431
// Report failure if bad return code, continue if good return code
continue if{ exists (exit codes of active action) whose(it = 1 OR it = 0) }
// http://support.bigfix.com/inspectors/World%20Objects_Any.html
// pending restart "DellUpdatesInstalled"
// Require reboot if return code = 1
if{ exists (exit codes of active action) whose(it = 1) }
action requires restart "DellUpdatesInstalled"
endif
// Check for Updates
// http://www.dell.com/support/Manuals/us/en/19/Topic/dell-comnd-update-v2.0/DCU_formerly_DCSU_UG-v2/en-us/GUID-5A058BEF-5A75-4037-A9C2-65628F818EB7
waithidden { pathname of file "dcu-cli.exe" whose(version of it >= "2.0.0.565") of folder ( unique value of pathnames of folders ( unique values of (it as string) of ( ( values "InstallLocation" of keys whose(value "DisplayName" of it as string as trimmed string starts with "Dell Command | Update" AND value "DisplayVersion" of it as string as version >= "2.0.0") of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of (registry;native registry) ) ; ( values "InstallPath" of keys "HKEY_LOCAL_MACHINE\SOFTWARE\Dell\CommandUpdate" of (registry;native registry) ) ) ) ) } /silent /report "{ (pathname of folder "__BESData\__Global\Logs" of parent folder of client) }\results_DellUpdate.xml" /log "{ (pathname of folder "__BESData\__Global\Logs" of parent folder of client) }\Logs_DellUpdate"
// Return Codes:
// 0 = OK/Success
// 1 = Reboot Required
// 2 = Fatal Error
// 3 = Error
// 4 = Invalid System
// http://www.dell.com/support/Manuals/us/en/19/Topic/dell-comnd-update-v2.0/DCU_formerly_DCSU_UG-v2/en-us/GUID-E3858402-1574-40EB-9ADB-3E9C4C9DB431
// Report failure if bad return code, continue if good return code
continue if{ exists (exit codes of active action) whose(it = 1 OR it = 0) }
// http://support.bigfix.com/inspectors/World%20Objects_Any.html
// pending restart "DellUpdatesInstalled"
// Require reboot if return code = 1
if{ exists (exit codes of active action) whose(it = 1) }
action requires restart "DellUpdatesInstalled"
endif
// Running this task will affect analysis properties, so this will force them to be updated right away
notify client ForceRefresh
This action will be considered successful when the applicability relevance evaluates to false.
Sharing
| Social Media: |
