Action 1 (default)

//  https://support.bigfix.com/inspectors/Fixlet%20Objects_Any.html
//  https://support.bigfix.com/inspectors/Action%20Objects_Any.html
//  https://forum.bigfix.com/t/action-parameters-in-actionscript/3345/2
//  https://forum.bigfix.com/t/newer-actionscript-commands/11677
// http://www-01.ibm.com/support/knowledgecenter/SS63NW_9.2.0/com.ibm.tivoli.tem.doc_9.2/Platform/Action/c_override.html


// ----------------------------------------------------------------------
//   How do I get these values?
//  Fixlet:
// x-bes-textfields-hash: sha256,?????
// Content-Type: text/html; charset=us-ascii
//  Action:
// mime-version: ??
// Content-Type: application/x-Fixlet-Windows-Shell
// fixlet-context: ????
// action-parameter: "action issue date"="???"

parameter "start" = "{now}"
parameter "test" = "testing"

pause while{ now - (it as time) of (parameter "start") < 2 * second }

delete __createfile

createfile until END_OF_FILE
ID: {id of active action}
origin fixlet id: {origin fixlet id of active action}

is this a multi-action group leader? : { group leader of active action }

is this an offer? : { offer of active action }
  offer accepted? : { offer accepted of active action }

pending time: {pending time of active action}
name of current site: {name of current site}

now: {now}

Action Taken Time: {parameter "action issue date" of action}
(now - Action_Taken_Time): { now - ( (it as time) of parameter "action issue date" of action ) }

Active_Start_Time: {active start time of active action}

(Active_Start_Time - Action_Taken_Time): { (active start time of active action) - ( (it as time) of parameter "action issue date" of action ) }

IDs of Actions:
{ concatenations "%0d%0a" of (it as string) of ids of actions }

Action Headers:
{ concatenation "%0d%0a" of (name of it & " = " & value of it) of headers of action | "ERROR" }

Fixlet Headers: 
{ concatenation "%0d%0a" of (name of it & " = " & value of it) of headers of fixlet whose(id of it = origin fixlet id of active action) of current site | "ERROR" }

  Total Execution Time, with 2 second pause:
(now - Active_Start_Time): { now - (active start time of active action) }

END_OF_FILE

if { windows of operating system }

delete C:\Users\Public\Documents\action_header_info.txt
move __createfile C:\Users\Public\Documents\action_header_info.txt

// http://www-01.ibm.com/support/knowledgecenter/SS63NW_9.2.0/com.ibm.tivoli.tem.doc_9.2/Platform/Action/c_override.html
override run
runas=currentuser
run notepad C:\Users\Public\Documents\action_header_info.txt

else

delete action_header_info.txt
move __createfile action_header_info.txt

endif