Fixlet | Adobe Flash Player - Enable Flash Player v11.2+ Silent Updates

Adobe Flash Player - Enable Flash Player v11.2+ Silent Updates
Log In or Register to download the BES file, and more.

0 Votes

Description

Applicable for adobe flash version 11.2 and later, not applicable to any machine with any flash version earlier than 11.2 installed, even if one of it's flash player versions is greater than 11.2

This action will enable silent automatic updates of the Adobe Flash Player. This will not prompt the user and will install silently even if the user does not has admin rights because it runs as a windows service under the SYSTEM account.

http://forums.adobe.com/message/4379612

http://www.adobe.com/devnet/flashplayer/articles/flash_player_admin_guide.html

http://www.adobe.com/devnet/flashplayer/articles/background-updater-windows.html

Property Details

ID	838
Title	Adobe Flash Player - Enable Flash Player v11.2+ Silent Updates
Domain	BESC
Category	Configuration
Download Size	0
Source ID	jgstew
Source Severity	<Unspecified>
Source Release Date	12/21/2012 12:00:00 AM
SANSID	N/A
Keywords	Adobe Flash Player, Flash, Updates
Is Task	True
Added by	jgstew on 12/21/2012 3:09:32 PM
Last Modified by	jgstew on 12/21/2012 3:09:32 PM
Counters	6553 Views / 10 Downloads
User Rating	* Average over 0 ratings. ** Log In or Register to add your rating.

Relevance

Relevance 247

Used in 365 fixlets

* Results in a true/false

(if( name of operating system starts with "Win" ) then platform id of operating system != 3 else false) AND (if exists property "in proxy agent context" then ( not in proxy agent context ) else true )

Relevance 268

Used in 257 fixlets and 9 analyses

* Results in a true/false

name of operating system as lowercase starts with "win"

Relevance 1578

Used in 3 fixlets

* Results in a true/false

(
    exists folder "macromed\flash" of system folder AND
    (
        exists file whose
        (
            (
                it starts with "flash" and it ends with ".ocx"
            )
            of
            (
                name of it as lowercase
            )
        )
        of folder "macromed\flash" of system folder OR exists file whose
        (
            (
                it starts with "swflash" and it ends with ".ocx"
            )
            of
            (
                name of it as lowercase
            )
        )
        of folder "macromed\flash" of system folder OR exists file whose
        (
            (
                it starts with "npswf32" and it ends with ".dll"
            )
            of
            (
                name of it as lowercase
            )
        )
        of folder "macromed\flash" of system folder
    )
)
OR
(
    exists key "HKLM\Software\Mozilla" whose
    (
        exists key whose
        (
            name of it does not contain "Netscape" AND exists key "Extensions" whose
            (
                exists file whose
                (
                    (
                        it starts with "npswf32" and it ends with ".dll"
                    )
                    of
                    (
                        name of it as lowercase
                    )
                )
                of folder
                (
                    value "Plugins" of it as string
                )
            )
            of it
        )
        of it
    )
    of registry
)

Relevance 1579

Used in 103 fixlets

* Results in a true/false

not exists values "PROCESSOR_ARCHITECTURE" whose (it as string as lowercase = "ia64") of keys "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" of registry

Relevance 1580

Used in 2 fixlets

* Results in a true/false

(exists folder "macromed\flash" of system folder) AND (exists file whose (((it starts with "flash" and it ends with ".ocx") OR (it = "swflash.ocx")) of (name of it as lowercase) and version of it >= "8.0") of it) of folder "macromed\flash" of system folder

Relevance 1581

Used in 2 fixlets

* Results in a true/false

(it != "WinNT" AND it != "Win95") of name of operating system

Relevance 1582

Used in 1 fixlet

* Results in a true/false

not exists keys whose (value "DisplayName" of it as string contains "Adobe Flash Player" AND (it < "11.2" as version) of (value "DisplayVersion" of it as string as version)) of key "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" of x32 registry

Relevance 1583

Used in 1 fixlet

* Results in a true/false

if
(
    not x64 of operating system
)
then
(
    not
    (
        exists file
        (
            system folder as string & "\Macromed\Flash\mms.cfg"
        )
        AND exists lines whose
        (
            it contains "AutoUpdateDisable" AND following text of first "=" of it contains "0" AND preceding text of first "AutoUpdateDisable" of it does not contain "#"
        )
        of file
        (
            system folder as string & "\Macromed\Flash\mms.cfg"
        )
        AND exists lines whose
        (
            it contains "SilentAutoUpdateEnable" AND following text of first "=" of it contains "1" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#"
        )
        of file
        (
            system folder as string & "\Macromed\Flash\mms.cfg"
        )
    )
)
else
(
    not
    (
        exists file
        (
            system wow64 folder as string & "\Macromed\Flash\mms.cfg"
        )
        AND exists lines whose
        (
            it contains "AutoUpdateDisable" AND following text of first "=" of it contains "0" AND preceding text of first "AutoUpdateDisable" of it does not contain "#"
        )
        of file
        (
            system wow64 folder as string & "\Macromed\Flash\mms.cfg"
        )
        AND exists lines whose
        (
            it contains "SilentAutoUpdateEnable" AND following text of first "=" of it contains "1" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#"
        )
        of file
        (
            system wow64 folder as string & "\Macromed\Flash\mms.cfg"
        )
    )
)

if (not x64 of operating system) then (not (exists file (system folder as string & "\Macromed\Flash\mms.cfg") AND exists lines whose (it contains "AutoUpdateDisable" AND following text of first "=" of it contains "0" AND preceding text of first "AutoUpdateDisable" of it does not contain "#") of file (system folder as string & "\Macromed\Flash\mms.cfg") AND exists lines whose (it contains "SilentAutoUpdateEnable" AND following text of first "=" of it contains "1" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#") of file (system folder as string & "\Macromed\Flash\mms.cfg"))) else (not (exists file (system wow64 folder as string & "\Macromed\Flash\mms.cfg") AND exists lines whose (it contains "AutoUpdateDisable" AND following text of first "=" of it contains "0" AND preceding text of first "AutoUpdateDisable" of it does not contain "#") of file (system wow64 folder as string & "\Macromed\Flash\mms.cfg") AND exists lines whose (it contains "SilentAutoUpdateEnable" AND following text of first "=" of it contains "1" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#") of file (system wow64 folder as string & "\Macromed\Flash\mms.cfg")))

Actions

Action 1 (default)

Action Link Click here to disable Flash Player Update.

Script Type BigFix Action Script

if {not x64 of operating system}
// If no MMS.CFG file exists, create one
if{not exists file (system folder as string & "\Macromed\Flash\mms.cfg")}
// if the Macromed folder does not exist, create it
if{not exists folder (system folder as string & "\Macromed\")}
dos mkdir {system folder as string & "\Macromed\"}
endif
// if the Macromed/Flash folder does not exist, create it
if{not exists folder (system folder as string & "\Macromed\Flash")}
dos mkdir {system folder as string & "\Macromed\Flash"}
endif
delete __createfile
delete mms.cfg
createfile until @end_create_mms_file
#Enable Adobe Flash auto update
AutoUpdateDisable=0
#require that auto updates be silent
SilentAutoUpdateEnable=1
@end_create_mms_file
move __createfile {system folder as string & "\Macromed\Flash\mms.cfg"}
else
//If an MMS.CFG file exists, then append "AutoUpdateDisable=0" & "SilentAutoUpdateEnable=1" to the MMS.CFG file, while removing any other: "AutoUpdateDisable","SilentAutoUpdateEnable","AutoUpdateInterval"
delete __appendfile
appendfile {concatenation "%0d%0a" of lines whose (not(it contains "AutoUpdateDisable" AND preceding text of first "AutoUpdateDisable" of it does not contain "#") AND not(it contains "SilentAutoUpdateEnable" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#") AND not(it contains "AutoUpdateInterval" AND preceding text of first "AutoUpdateInterval" of it does not contain "#")) of file (system folder as string & "\Macromed\Flash\mms.cfg")}
appendfile {"%0d%0a"}AutoUpdateDisable=0
appendfile {"%0d%0a"}SilentAutoUpdateEnable=1
//backup
delete "{(system folder as string & "\Macromed\Flash\mms.cfg.bak")}"
move "{(system folder as string & "\Macromed\Flash\mms.cfg")}" "{(system folder as string & "\Macromed\Flash\mms.cfg.bak")}"
delete {(system folder as string & "\Macromed\Flash\mms.cfg")}
copy __appendfile {(system folder as string & "\Macromed\Flash\mms.cfg")}
endif
else //End of 32bit, start of 64bit:
// If no MMS.CFG file exists, then create one
if{not exists file (system wow64 folder as string & "\Macromed\Flash\mms.cfg")}
// if the Macromed folder does not exist, create it
if{not exists folder (system wow64 folder as string & "\Macromed\")}
dos mkdir {system wow64 folder as string & "\Macromed\"}
endif
// if the Macromed/Flash folder does not exist, create it
if{not exists folder (system wow64 folder as string & "\Macromed\Flash")}
dos mkdir {system wow64 folder as string & "\Macromed\Flash"}
endif
delete __createfile
delete mms.cfg
createfile until @end_create_mms_file
#Enable Adobe Flash auto update
AutoUpdateDisable=0
#require that auto updates be silent
SilentAutoUpdateEnable=1
@end_create_mms_file
move __createfile {system wow64 folder as string & "\Macromed\Flash\mms.cfg"}
else
//If an MMS.CFG file exists, then append "AutoUpdateDisable = 1" to the MMS.CFG file, while removing any other "AutoUpdateDisable"'s
delete __appendfile
appendfile {concatenation "%0d%0a" of lines whose (not(it contains "AutoUpdateDisable" AND preceding text of first "AutoUpdateDisable" of it does not contain "#") AND not(it contains "SilentAutoUpdateEnable" AND preceding text of first "SilentAutoUpdateEnable" of it does not contain "#") AND not(it contains "AutoUpdateInterval" AND preceding text of first "AutoUpdateInterval" of it does not contain "#")) of file (system wow64 folder as string & "\Macromed\Flash\mms.cfg")}
appendfile {"%0d%0a"}AutoUpdateDisable=0
appendfile {"%0d%0a"}SilentAutoUpdateEnable=1
//backup
delete "{(system wow64 folder as string & "\Macromed\Flash\mms.cfg.bak")}"
move "{(system wow64 folder as string & "\Macromed\Flash\mms.cfg")}" "{(system wow64 folder as string & "\Macromed\Flash\mms.cfg.bak")}"
delete {(system wow64 folder as string & "\Macromed\Flash\mms.cfg")}
copy __appendfile {(system wow64 folder as string & "\Macromed\Flash\mms.cfg")}
endif
endif

Success Criteria

This action will be considered successful when the applicability relevance evaluates to false.

Sharing

Social Media:

Search for:	Relevance	Fixlets/Tasks
	Analyses	BFI Signatures
	Dashboard/Wizard

Title	Keywords	Description
Relevance	Domain	ActionScript
Mime	Signature Content	(clear all)


Content Search Share Learn Projects	Utilities View SCM Scripts Base64 Converter Shell to Action Script	About About Us Tour FAQ Terms Contact Us	BigFix Resources Download BigFix Support Forum Github/Bigfix

Adobe Flash Player - Enable Flash Player v11.2+ Silent Updates Log In or Register to download the BES file, and more.

Description

Property Details

Relevance

Actions

Action 1 (default)

Sharing

Comments

Content

Utilities

About

BigFix Resources

Adobe Flash Player - Enable Flash Player v11.2+ Silent Updates
Log In or Register to download the BES file, and more.