if
(
windows of operating system
)
then
(
(
name of it, it as string
)
of values whose
(
name of it starts with "Collect"
)
of keys "HKLM\Software\CarbonBlack\config" of native registry
)
else if
(
(
exists match
(
regex "Linux CentOS (6|7)"
)
of name of operating system
)
OR
(
(
name of operating system starts with "Linux Red Hat"
)
AND
(
exists file "/etc/redhat-release" whose
(
exists line whose
(
exists match
(
regex "Red Hat Enterprise Linux (Client|Server|Workstation) release 6|7"
)
of it
)
of it
)
AND NOT exists file "/etc/vmware-release" whose
(
exists line whose
(
it contains "VMware ESX"
)
of it
)
AND NOT exists file "/etc/enterprise-release" whose
(
exists line whose
(
it contains "Enterprise Linux Enterprise Linux"
)
of it
)
)
)
)
then
(
(
(
preceding texts of firsts "=" of it
)
as string,
(
following texts of firsts "=" of it
)
as string
)
of lines whose
(
it as string starts with "Collect"
)
of files "/var/lib/cb/sensorsettings.ini"
)
else
(
"n/a","n/a"
)
if (windows of operating system) then ((name of it, it as string) of values whose (name of it starts with "Collect") of keys "HKLM\Software\CarbonBlack\config" of native registry) else if ((exists match (regex "Linux CentOS (6|7)") of name of operating system) OR ((name of operating system starts with "Linux Red Hat") AND (exists file "/etc/redhat-release" whose (exists line whose (exists match (regex "Red Hat Enterprise Linux (Client|Server|Workstation) release 6|7") of it) of it) AND NOT exists file "/etc/vmware-release" whose (exists line whose (it contains "VMware ESX") of it) AND NOT exists file "/etc/enterprise-release" whose (exists line whose (it contains "Enterprise Linux Enterprise Linux") of it)))) then (((preceding texts of firsts "=" of it) as string, (following texts of firsts "=" of it) as string) of lines whose (it as string starts with "Collect") of files "/var/lib/cb/sensorsettings.ini") else ("n/a","n/a")
