(
(
(
sum of sizes of files of folders of folders of it
)
+
(
sum of sizes of files of it
)
)
of folder "sha1" of folder
(
if
(
(
exists setting "_BESRelay_UploadManager_BufferDirectory" of it and exists value of setting "_BESRelay_UploadManager_BufferDirectory" of it
)
of client
)
then
(
value of setting "_BESRelay_UploadManager_BufferDirectory" of client as string
)
else
(
if
(
name of operating system starts with "Win"
)
then
(
parent folder of parent folder of client as string & "\BES Relay\UploadManagerData\BufferDir"
)
else
(
"/var/opt/BESRelay/UploadManagerData/BufferDir"
)
)
)
>= it
)
of
(
if
(
(
exists setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of it and exists value of setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of it
)
of client
)
then
(
value of setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of client as integer
)
else
(
20971520
)
)
(((sum of sizes of files of folders of folders of it) + (sum of sizes of files of it)) of folder "sha1" of folder (if ((exists setting "_BESRelay_UploadManager_BufferDirectory" of it and exists value of setting "_BESRelay_UploadManager_BufferDirectory" of it) of client) then (value of setting "_BESRelay_UploadManager_BufferDirectory" of client as string) else (if (name of operating system starts with "Win") then (parent folder of parent folder of client as string & "\BES Relay\UploadManagerData\BufferDir") else ("/var/opt/BESRelay/UploadManagerData/BufferDir"))) >= it) of (if ((exists setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of it and exists value of setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of it) of client) then (value of setting "_BESRelay_UploadManager_BufferDirectoryMaxSize" of client as integer) else (20971520))
