if
(
(
it starts with "127." OR it starts with "::"
)
of
(
name of registration server as string
)
)
then
(
"n/a (Local Relay/Server)"
)
else
(
if
(
(
exists setting "__RelaySelect_Automatic" of client
)
and
(
value of setting "__RelaySelect_Automatic" of client = "1"
)
)
then "n/a (Automatic)" else if
(
(
not exists setting "__RelayServer1" of client OR not exists value of setting "__RelayServer1" of client OR value of setting "__RelayServer1" of client = ""
)
AND
(
not exists setting "__RelayServer2" of client OR not exists value of setting "__RelayServer2" of client OR value of setting "__RelayServer2" of client = ""
)
)
then "Primary and Secondary Relay Not Set" else if
(
(
exists setting "__RelayServer1" of client
)
AND
(
exists setting "__RelayServer1" whose
(
value of it as string != ""
)
of client
)
AND
(
(
preceding text of first "/" of following text of first "//" of
(
value of setting "__RelayServer1" of client as string
)
)
as lowercase
)
=
(
name of registration server as string as lowercase
)
)
then "Using Primary Relay" else if
(
(
exists setting "__RelayServer2" of client
)
AND
(
exists setting "__RelayServer2" whose
(
value of it as string != ""
)
of client
)
AND
(
(
preceding text of first "/" of following text of first "//" of
(
value of setting "__RelayServer2" of client as string
)
)
as lowercase
)
=
(
name of registration server as string as lowercase
)
)
then "Using Secondary Relay" else if
(
(
name of registration server as string as lowercase
)
=
(
preceding text of first "/" of following text of first "//" of
(
value of setting "__Relay_Control_RootServer" of client as string as lowercase
)
)
)
then "Defaulting to Main BES Server" else "Unknown State"
)
if ((it starts with "127." OR it starts with "::") of (name of registration server as string)) then ("n/a (Local Relay/Server)") else(if ((exists setting "__RelaySelect_Automatic" of client) and (value of setting "__RelaySelect_Automatic" of client = "1")) then "n/a (Automatic)" else if ((not exists setting "__RelayServer1" of client OR not exists value of setting "__RelayServer1" of client OR value of setting "__RelayServer1" of client = "") AND (not exists setting "__RelayServer2" of client OR not exists value of setting "__RelayServer2" of client OR value of setting "__RelayServer2" of client = "")) then "Primary and Secondary Relay Not Set" else if ((exists setting "__RelayServer1" of client) AND (exists setting "__RelayServer1" whose (value of it as string != "") of client ) AND ((preceding text of first "/" of following text of first "//" of (value of setting "__RelayServer1" of client as string)) as lowercase) = (name of registration server as string as lowercase)) then "Using Primary Relay" else if ((exists setting "__RelayServer2" of client) AND (exists setting "__RelayServer2" whose (value of it as string != "") of client ) AND ((preceding text of first "/" of following text of first "//" of (value of setting "__RelayServer2" of client as string)) as lowercase) = (name of registration server as string as lowercase)) then "Using Secondary Relay" else if ((name of registration server as string as lowercase) = (preceding text of first "/" of following text of first "//" of (value of setting "__Relay_Control_RootServer" of client as string as lowercase))) then "Defaulting to Main BES Server" else "Unknown State")
