Action 1 (default)

begin prefetch block
 if {version of operating system >= version "6"}
    add prefetch item name=LGPO.exe sha1=f5a4a8e27b428c2d9a1c1ba7d72ba08b77406a9c size=380208 url=http://MANUAL_BES_CACHING_REQUIRED/LGPO.exe sha256=a8e0b52dea3836071f3f46235c126cb7fe986abdcc3d1b819d7c2cd101999cb3
  else
    add prefetch item name=ImportRegPol.exe sha1=69d4881eb10a8f8c121e9ea63323ba6bfc028f31 size=181248 url=http://MANUAL_BES_CACHING_REQUIRED/ImportRegPol.exe
 endif
 collect prefetch items
end prefetch block


action uses wow64 redirection false
if {version of operating system >= version "6"}
    parameter "LGPO"="{pathname of download file "LGPO.EXE"}"
    utility __Download\LGPO.exe
    else
    parameter "LGPO"="{pathname of download file "ImportRegPol.EXE"}"
    utility __Download\ImportRegPol.exe
endif

// Path of each registry.pol file to parse, and the context (Computer|User) for the settings
// Split via ";", ", /u" refers to User and ", /m" refers to Machine
// Check Machine\Registry.pol, User\Registry.pol, and each potential MLGPO folder at System32\GroupPolicyUsers
parameter "Registry.pol"="{pathname of system folder}\GroupPolicy\Machine\Registry.pol, /m;{pathname of system folder}\GroupPolicy\User\Registry.pol, /u{(if it !="" then ";" & it else "") of concatenation ";" of (it & ", /u") of pathnames of files "Registry.pol" of folders of folders "GroupPolicyUsers" of native system folder}"

// Registry key into which we are going to write the output settings -
parameter "RootKey"="HKEY_LOCAL_MACHINE\Software\BES_LGPO"

// Locate Registry.pol and export it to LGPO Text file
delete __appendfile
// This creates a .inf file corresponding to each Registry.pol file found
// Output .INF files are saved in the __Download folder (taking advantage of the BES Client behavior of keeping the download folder clean)
// Files are named for the parent folder of Registry.pol - should be "Machine", "User", or the SID for an MLGPO user object
// Output is generated by LGPO.exe or ImportRegPol.exe depending on OS
// IF EXIST "PATH\Registry.pol" "PATH\LGPO.EXE" /parse /m "PATH\registry.pol" > __Download\parentdir.inf 2>>__Download\Export_Registry_Pol.err || EXIT /B 1
if {version of operating system >= version "6"}
    appendfile {concatenation "%0d%0a" of ("IF EXIST %22" & tuple string item 0 of it & "%22 %22" & parameter "LGPO" & "%22 /parse " & tuple string item 1 of it & " %22" & tuple string item 0 of it & "%22 > __Download\"  & (following text of last "\" of preceding text of last "\" of tuple string item 0 of it) & ".inf 2>>__Download\Export_Registry_Pol.err || EXIT /B 1" ) of substrings separated by ";" of parameter "Registry.pol"}
else
    appendfile {concatenation "%0d%0a" of ("IF EXIST %22" & tuple string item 0 of it & "%22 %22" & parameter "LGPO" & "%22 " & tuple string item 1 of it  & "  %22" & tuple string item 0 of it & "%22 /parseOnly /log __Download\"  & (following text of last "\" of preceding text of last "\" of tuple string item 0 of it) & ".inf /error __Download\Export_Registry_Pol.err || EXIT /B 1" ) of substrings separated by ";" of parameter "Registry.pol"}
endif

delete ExportRegistryPol.cmd
move __appendfile ExportRegistryPol.cmd

waithidden cmd /c ExportRegistryPol.cmd
// Check for ExportRegistryPol.cmd error output
continue if {not exists lines whose (it contains "Error") of files "Export_Registry_Pol.err" of download folder }

// If we failed to export any of the registry.pol files to INF, stop here, leaving the prior Registry entries intact
continue if {exit code of action = 0}

// All targeted Registry.pol files have been exported.
// Delete the output Registry key, 
//  insert a new CaptureTime, and import all of the outputted Registry.inf files
delete __appendfile
appendfile reg.exe delete "{parameter "RootKey"}" /F
appendfile reg.exe add "{parameter "RootKey"}" /v __CaptureTime /t REG_SZ /d "{now}" /F

appendfile SET RETCODE=0
// Include handling for special cases:
//  if "value name" is empty substitute "(default)"
//  escape any embedded quotes with backslash (%22 ==> \%22 )
//  Double-up on any embedded percent signs (  %25 ==> %25%25 )
//

appendfile {concatenation "%0d%0a" of ("reg.exe add %22HKLM\Software\BES_LGPO\" & preceding text of last ".inf" of name of item 3 of it /* Removed: naming the key for "computer" or "user", that's evident already :: & "\" & item 0 of it */ & "%22 /v %22" & item 1 of it & "%22 /t REG_SZ /d %22" & item 2 of it & "%22 /F || SET RETCODE += 1") of ((item 0 of it, next line of item 0 of it & "\" & (if it as trimmed string = "" then "(default)" else it) of next line of next line of item 0 of it, concatenation "\%22" of substrings separated by "%22" of concatenation "%25%25" of substrings separated by "%25" of  next line of next line of next line of item 0 of it, item 1 of it)) of (lines whose (previous line of it = "" and it as trimmed string as lowercase = "computer" or it as trimmed string as lowercase = "user") of it, it) of files whose (name of it as lowercase ends with ".inf") of download folder}
appendfile exit /B %RETCODE%

delete regadd.cmd
move __appendfile regadd.cmd
waithidden cmd /c regadd.cmd

// If any of the REG ADD commands failed, the batch will return a non-zero code which we should flag here
continue if {exit code of action = 0}

// Even if we try to force a GPUpdate, the Policies registry key may not update until reboot
runhidden gpupdate.exe /target:computer /wait:0


// ---- Only comments beyond this line ------

// Example .inf file format
//; ----------------------------------------------------------
//; PARSING COMPUTER POLICY
//; Source file:  Registry.pol

//Computer
//Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
//NoInternetOpenWith
//DWORD:1
//
//Computer
//Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
//NoOnlinePrintsWizard
//DWORD:1
//
//Computer
//Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
//PreXPSP2ShellProtocolBehavior
//DWORD:0
//
//Computer
//Software\Microsoft\Windows\CurrentVersion\Policies\Explorer
//DisableLocalMachineRunOnce
//DWORD:1
//
// Parsing logic:
//  * Grab a list of .inf files, and preserve their names (filename is used in naming the output registry key)
//  * Find a line that is only "Computer" or "User", preceded by an empty line
//  * Grab that line (Computer|User), and the three lines after it, as items
//  * The first line (Computer|User) is ignored.  Line 2 and 3 are concatenated to make a registry value name (like Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\DisableLocalMachineRunOnce).  If line 3 is empty replace it with (default)
//  * The fourth line is used as the value data (DWORD:1).  
// Include handling for special cases:
//  if "value name" is empty substitute "(default)"
//  escape any embedded quotes with backslash (%22 ==> \%22 )
//  Double-up on any embedded percent signs (  %25 ==> %25%25 )